•

# Warning for Torodo: 1. All posters are to make an effort to communicate clearly.

No replies to this topic

### #1 Vulajin

Vulajin

Vula'jin the Void, blessed by the loa

• Moderators
• 5924 posts

Posted 02 March 2009 - 10:27 PM

Post: [Resto] Healing Equivalency Points
User: Torodo
Infraction: 1. All posters are to make an effort to communicate clearly.
Points: 0

Message to User:

Original Post:

TLDR:

+1 INT = 3.5 HEP
+1 MP5 = 2 HEP
+1 Spell Power = +1 HEP
+1 Crit Rating = 0.5 HEP
+1 Haste Rating = 0 HEP

The Long Version:

I have played a priest and druid in raiding content, and am now gearing up my shaman for healing with the advent of 3.1 and dual speccing.

A very successful approach I used for the other two classes was to focus in my Oh Sh1t spell and figure out what combination of stats would return the largest TOTAL healing before I go OOM.

This approach has a very practical application for dungeon and raid progression, because when things go bad, as they frequently do, a wipe is usually saved by being able to cast a fast heal for a very long time.

By gearing to this worst case scenario, I found, anecdotally to be sure, that when things are going smoothly, healing is easy and trivial.

Please be warned: I am not saying this is the "best" approach. YMMV depending on the specific needs of your guild and the challenges of specific boss fights you may be stuck on.

I AM saying that this has been very effective for me to quantify gearing decisions for PvE progression content through end-game raiding.

1. Compute the Healing per Second of the spell you want to optimize. For LHW, a "simple" estimate:

hps = (1.0 + (cr/4591.0 + itl/16700.0)/2)*(1738 + 0.808*hp)*(1.0 + hr/3300.0)/1.5

cr = crit rating
itl = intellect
hp = healing power
hr = haste rating

2. Compute your mana consumption rate while spamming the spell:

mps = (645*(1.0 + hr/3300.0)/1.5) - (mp5/5.0)

3. COmpute the time to go OOM at that consumption rate

tOOM = m/mps

m = total mana at the start

4. Total Healing to OOM is:

hOOM = hps * tOOM

The following vb script computes the effect of adding various stats to the total healing output, normalized for spell power = 1.

You can easily modify it for other spells. It might be nice to extend it to include various talent effects, like mana tide, tidal force and improved ws procs. I will leave it to some ambitious reader as an exercise.

```Option Explicit
Dim hp, m, hr, mp5, itl, cr
Dim hBase, hHP, hINT, hHR, hMP5, hCR
Dim msg

'*** intelligence
itl = 878             '*** gear
itl = itl + 60        '*** dalaran intellect

'*** healing power: include EL weapon, FT totem, food buffs, average trinket procs, etc
hp = 1900

'*** mana pool
m = 17300               '*** gear
m = m + 15*60           '*** dalaran intellect

'*** haste rating
hr = 166                '*** gear
hr = hr + 33*5          '*** wrath totem

'*** mp5
mp5 = 243               '*** gear + water shield
mp5 = mp5 + 16          '*** food buff
mp5 = mp5 + 5*42/2      '*** mana spring

'*** crit rating
cr = 90                 '*** gear
cr = cr + 46*2.2        '*** base shaman crit rate
cr = cr + 46*5          '*** thundering strikes
cr = cr + 46*5          '*** tidal mastery

hBase = TotalLHW(hp, m, hr, mp5, cr, itl)
hHP = TotalLHW(hp+1, m, hr, mp5, cr, itl)
hINT = TotalLHW(hp, m+15, hr, mp5, cr, itl+1)
hHR = TotalLHW(hp, m, hr+1, mp5, cr, itl)
hMP5 = TotalLHW(hp, m, hr, mp5+1, cr, itl)
hCR = TotalLHW(hp, m, hr, mp5, cr+1, itl)

msg = Round(hBase,0) & " Total LHW Healing" & vbcrlf
msg = msg & Round(hHP-hBase,2) & " Extra Healing from +1 spell power" & vbcrlf
msg = msg & "1 HEP from +1 Spell Power" & vbcrlf
msg = msg & Round((hINT-hBase)/(hHP-hBase),2) & " HEP from +1 INT" & vbcrlf
msg = msg & Round((hHR-hBase)/(hHP-hBase),2) & " HEP from +1 Haste Rating" & vbcrlf
msg = msg & Round((hCR-hBase)/(hHP-hBase),2) & " HEP from +1 Critical Rating" & vbcrlf
msg = msg & Round((hMP5-hBase)/(hHP-hBase),2) & " HEP from +1 MP5"
MsgBox msg

wscript.quit(0)

Function TotalLHW(hp, m, hr, mp5, cr, itl)
Dim hps, mps, tOOM

'*** lesser healing wave heal per second
hps = (1.0 + (cr/4591.0 + itl/16700.0)/2)*(1738 + 0.808*hp)*(1.0 + hr/3300.0)/1.5

'*** mana consumption rate
mps =  (645*(1.0 + hr/3300.0)/1.5) - (mp5/5.0)

'*** total cast time before OOM
tOOM = m/mps

'*** total healing before OOM
TotalLHW = hps * tOOM
End Function```

#### 0 user(s) are reading this topic

0 members, 0 guests, 0 anonymous users